pro gte_readvar,name,data,vardesc,path=path,flight=flight

   ; read data from one GTE binary file.
   ; NAME may be string array.
   ; file is looked up automatically from the *last* element in NAME

   FORWARD_FUNCTION gte_findvar

   data = 0
   if (n_elements(path) eq 0) then path = '/data/pem-t/dc8/binary/'

   if (n_elements(name) eq 0) then return

   if (n_elements(flight) eq 0) then $
      read,flight,prompt='FLIGHT : ' 
   flight = fix(flight)

   for i=0,n_elements(name)-1 do begin
      if (gte_findvar(name[i],result)) then begin
         filename = result.file 
         if (n_elements(species) eq 0) then species = result.name $
         else species = [ species, result.name ]
      endif else begin
         message,'Could not find variable '+name[i],/Cont
         if (i eq n_elements(name)-1) then return  ; last one must be there!
      endelse
   endfor

   if (n_elements(species) eq 0) then begin
       message,'No variables found in list !',/Cont
       return
   endif

 
   ; construct the filename 
   strflight = string(flight,format='(i2.2)')
   realname = path + replace_token(filename,'*',strflight,delim='')

   ; now read in the binary data file 
   gte_readbin,realname,data,vardesc

   if (n_elements(data) lt 2) then begin
       message,'No data read!',/Cont
       return
   endif

   ; extract selected variables
   sel = make_selection(vardesc.name,species)

   if (min(sel) lt 0) then $ 
       message,'Oops! Variables not found: '+ $
              string(species[sel[where(sel lt 0)]],format='(255(A,1X))') 

   data = data[*,sel]
   vardesc = vardesc[sel]

   return
end